****************************************************************************************************
** LNG product:		ELISA source
****************************************************************************************************
** Type:               			Sequence 
**  
** FOP Name & Version: 			None 
**
** Description:                    	The following sequence performs the following steps :-
**								- Switch off SWA EAS
**					
**
** Input Arguments:				None
**								
**
** Output Values:					None
**
** CSW Version:					V2.1.3 or higher
** 
** FOPs used:						None 
**
** HK TM packets used:				
**
** Test Procedure & Reference:		SO-SWA-MSSL-TOP-059 Issue 1 Section 6.1
**
** Restrictions and Limitations: 	SSMM hardware required to be on before switch ON.
**								SWA EAS ON
**								SWA DPU to be On in OPS mode.     
**
****************************************************************************************************
**	History
**--------------------------------------------------------------------------------------------------
**	Version	Date			Author			Comment
**--------------------------------------------------------------------------------------------------
**	1.1		28/04/2018	J Silverthorn		Initial version
**	1.2		01/05/2018	E Boulet			Correct typo in titles/header
**	1.3		14/02/2019	J Silverthorn		Added proto $TM
***************************************************************************************************

** SEQUENCE TISS_EAS_OFF

SEQUENCE TISS_EAS_OFF
** Definition of Input parameters
	proto
		string		$sUnit := "1" ["1", "2"]
		string		$TM := "YES"	["YES", "NO"]
	end proto

** Definition of Constants
	const
		string   		$sTitle  		:= "TITLE"  
		string		$sTrace 		:= "TRACE"

** Definition of Variables
	var
		string		$sBufArg := ""
		string		$sNumPha
		string		$sPlatform	
		date			$dCurDate
	
		int 			$Count

		string 		$s_lcl_a_cur := "AB.TM.NPWD3267"											--IFA_LCL4_LCL16 SWA-A_LCL TM
		string		$s_lcl_b_cur := "AB.TM.NPWD2768"											--IFA_LCL2_LCL17 SWA-B PWR_LCL TM
		string 		$s_lcl_a_sts := "AB.TM.NPWD0077"											--IFA_LCL4_LCL16 SWA-A_LCL ST
		string		$s_lcl_b_sts := "AB.TM.NPWD0038"											--IFA_LCL2_LCL17 SWA-B PWR_LCL ST
		string 		$s_rsa_a_sts := "AB.TM.NRUD2007"											--Acq. RSA_1_1_9 SWA A
		string		$s_rsa_b_sts := "AB.TM.NRUD2067"											--Acq. RSA_2_1_9 SWA B

		string 		$sTTRM
		string 		$sPM
		string 		$sRIU
		string		$sPCDU
		string		$sMilBus	

		string		$sRSA_A
		string		$sRSA_B


	main
		window

		@SU_SEQSTART("Switching SWA EAS side - "+$sUnit+" OFF", *$dCurDate, $sTrace, "")
		$sPlatform := AB.USR.PLATFORM

		if ($TM = "YES")
			@TPZC_PSFT_CONFIG(*$sTTRM,*$sPM,*$sRIU,*$sPCDU,*$sMilBus)
			
			if ($sPCDU = "B")
				$s_lcl_a_cur := "AB.TM.NPWT3267"
				$s_lcl_b_cur := "AB.TM.NPWT2768"
				$s_lcl_a_sts := "AB.TM.NPWT0077"
				$s_lcl_b_sts := "AB.TM.NPWT0038"
			endif
			if ($sRIU = "B")
				$s_rsa_a_sts := "AB.TM.NRUT2007"
				$s_rsa_b_sts := "AB.TM.NRUT2067"
			endif
			
			********************************************************************
			@SU_SEQPHASE2(1, "Initial checks", *$sNumPha, "",  $sTitle)
			********************************************************************
			
			@su_digacs($s_lcl_a_sts,"NO","NO", $sTrace, 5) 
			@su_digacs($s_lcl_b_sts,"NO","NO", $sTrace, 5) 
			@su_digacrs($s_rsa_a_sts,"NO","NO", *$sRSA_A, $sTrace, 5) 
			@su_digacrs($s_rsa_b_sts,"NO","NO", *$sRSA_B, $sTrace, 5) 
			@su_anaacs($s_lcl_a_cur,"NO","NO",$sTrace, 60) 
			@su_anaacs($s_lcl_b_cur,"NO","NO",$sTrace, 60) 
			
			if (($sRSA_A = "Off") and ($sRSA_B = "Off"))
				ta_print "Error SWA DPU is OFF - please check"
				Return "INIT_NOK"
			end if
			
			@su_digacs("AB.TM.NIAD0703","=","OPS", $sTrace, 5) 
			
		endif
		
		@SU_SEQPHASE2(1, "Switch EAS"+$sUnit+" Off", *$sNumPha, "",  $sTitle)	

		if ($sUnit = "1")

			@SU_SEQPHASE2(2, "Put EAS1 into no science mode", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58771 , \
				PIA60031_ := "MBOX1" , \
				PIA60446_ := 0 , \
				PIA60447_ := 0 , \
				PIA60448_ := 0 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)

			@SU_SEQPHASE2(2, "Power down EAS1", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58761 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)

			@su_wait(60)

			if ($TM = "YES")
				@SU_SEQPHASE2(2, "Checking EAS1 is OFF", *$sNumPha, "",  $sTitle)	
				@su_anaacs("AB.TM.NIA00833", ">=0","<=20", $sTrace, 60)
			endif

		endif

		if ($sUnit = "2")

			@SU_SEQPHASE2(2, "Put EAS2 into no science mode", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58819 , \
				PIA60031_ := "MBOX1" , \
				PIA60446_ := 0 , \
				PIA60447_ := 0 , \
				PIA60448_ := 0 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)

			@SU_SEQPHASE2(2, "Power down EAS2", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58809 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)

			@su_wait(60)

			if ($TM = "YES")
				@SU_SEQPHASE2(2, "Checking EAS2 is OFF", *$sNumPha, "",  $sTitle)	
				@su_anaacs("AB.TM.NIA00832", ">=0","<=20", $sTrace, 60)
			endif

		endif
	
end sequence