****************************************************************************************************
** LNG product   : ELISA source
****************************************************************************************************
** Type:                            Test Sequence
**
** Description:                     Test sequence used to start and stop normal mode for HIS (extracted from SFT section 8.1)
**
** Input Arguments:			    sModeTrans :  Define the transition mode to be executed
** 
** Output Values:                   None                
**
** CSW Version:                     Version 2.1.3
**
** FOPs used (name & version):      N/A
**
** TM Packets Used:                 N/A
**
** Test Spec & Reference:           None
**
** Restrictions and Limitations:    N/A
**
****************************************************************************************************
** History
**--------------------------------------------------------------------------------------------------
** Version   Date         Author            Comment
**--------------------------------------------------------------------------------------------------
** 1.2		17/05/2018	E. Boulet			Initial creation.
** 1.3		14/02/2019	J Silverthorn		Added proto $TM - not needed
** 1.4		01/05/2019					Added HIS Burst mode
** 1.5		10/05/2019					ACS_EVT_408 OBS PAY4 - YIA58982 not available when TM = NO
****************************************************************************************************  
sequence TISS_HIS_MOD_MNG
	
	-- Define entry arguments
	PROTO
		string 	$sModeTrans 		["STBY2NORMAL","NORMAL2STBY", "BURST"]      -- Choose which mode transition shall be performed
		string 	$TM := "YES"		["YES", "NO"]
		int		$iBurst_Duration := 2400 -- 2400 = 5 minutes in 1/8 second intervals
	END PROTO	

	CONST
		string	$s_Trace := "TRACE"	
	-- Define variables	
	VAR
		date 	$dCurDate
		int		$i_reportflowID(7)
		int		$i_RptRefNb
		int		$iWait
		int		$i

	-- Main sequence
	MAIN
		WINDOW
		@su_seqstart("Start TISS_HIS_MOD_MNG", *$dCurDate, "TRACE")		
		
		--Mode transition extracted from SFT section 8.1
		
		SWITCH $sModeTrans
			Case "STBY2NORMAL"
				@HIS_STBY2NORMAL()
				
				--
			Case "NORMAL2STBY"				
				@HIS_NORMAL2STBY()

			Case "BURST"
				TA_PRINT "Put SWA HISinto Burst mode for "+%d($iWait)+" minutes"
	
				$i_reportflowID(1) := startreportflow("AB.TM.YIA58602")
				
				$i_reportflowID(2) := startreportflow("AB.TM.YIA58806")
				$i_reportflowID(3) := startreportflow("AB.TM.YIA58805")
				$i_reportflowID(4) := startreportflow("AB.TM.YIA58801")
				$i_reportflowID(5) := startreportflow("AB.TM.YIA58811")
				$i_reportflowID(6) := startreportflow("AB.TM.YIA58982")
				
				@su_send({ AB.TC.ZIA58913 , \
				SHF:OBV := 0 , \
				SID:OBV := 120 , \
				PIA60001_ := 5 }, $s_Trace)
				
				@su_wait(60)

				if ($TM = "YES")
					@RPZA_CATCHTMPCKT($i_reportFlowID(6), "AB.TM.YIA58982", *$i_RptRefNb, 360)
				endif

				@su_send({ AB.TC.ZIA58726 , \
				SHF:OBV := 0 , \
				SID:OBV := 120 , \
				PIA60157_ := 0 , \
				PIA60158_ := 0 , \
				PIA60159_ := 0 , \
				PIA60160_ := 0 , \
				PIA60163_ := 0 , \
				PIA60164_ := 0 , \
				PIA60170_ := "DYNAMIC" , \
				PIA60161_ := $iBurst_duration , \
				PIA60162_ := 0 }, $s_Trace)

				$iWait := ($iBurst_duration / 480)

				@RPZA_CATCHTMPCKT($i_reportFlowID(1), "AB.TM.YIA58602", *$i_RptRefNb,10)

				TA_PRINT "After "+%d($iWait)+" minutes SWA HIS returns to Normal mode"
					
				if ($TM = "YES")
					
					-- Needs VCID3
					@RPZA_CATCHTMPCKT($i_reportFlowID(2), "AB.TM.YIA58806", *$i_RptRefNb, 10)
					@RPZA_CATCHTMPCKT($i_reportFlowID(3), "AB.TM.YIA58805", *$i_RptRefNb, 10)
					@RPZA_CATCHTMPCKT($i_reportFlowID(4), "AB.TM.YIA58801", *$i_RptRefNb, 10)

				endif

				@su_wait($iWait*60)

				if ($TM = "YES")

					-- Needs VCID3
					@RPZA_CATCHTMPCKT($i_reportFlowID(5), "AB.TM.YIA58811", *$i_RptRefNb, 60)
					
				endif

				-- No need for VCID3
				@RPZA_CATCHTMPCKT($i_reportFlowID(1), "AB.TM.YIA58602", *$i_RptRefNb, 60)
				
				stopreportflow $i_reportflowID(1)
				stopreportflow $i_reportflowID(2)
				stopreportflow $i_reportflowID(3)
				stopreportflow $i_reportflowID(4)
				stopreportflow $i_reportflowID(5)

				ta_print  "SWA HIS Burst mode is complete"

			default
		ENDSWITCH
		
		@SU_SEQEND("END OF SEQUENCE TISS_HIS_MOD_MNG", $dCurDate)
		
END SEQUENCE

******************************************
**************ROUTINES
******************************************

*****************************************
**ROUTINE HIS_STBY2NORMAL
**Routine to switch HIS mode the Normal (generate science data)
*****************************************
ROUTINE HIS_STBY2NORMAL


	--Define constant
	CONST
	string $s_Trace := "TRACE"
	
	-- Define variables	
	VAR
	date $dCurDate
	int $i_reportFlowID
	int $i_RptRefNb	
	
	MAIN	
		
		TA_PRINT "Put HIS into normal mode"
		
		--; Put HIS into science mode 
		--TC, ZIA58917, PIA59011, EQUAL, NORMAL_SCI
		
		$i_reportflowID := startreportflow("AB.TM.YIA58602")
		
		--TC, ZIA58917, PIA59011, EQUAL, NORMAL_SCI
		@su_send({ AB.TC.ZIA58917 , \
		SHF:OBV := 0 , \
		SID:OBV := 120 , \
		PIA59011_ := "NORMAL_SCI"}, $s_Trace)	
		
		--; Reception of:
		--TM,YIA58602 ; (5,1) SID=43802 SWA_E_HIS_MODE_CHANGE 
		@RPZA_CATCHTMPCKT($i_reportFlowID, "AB.TM.YIA58602", *$i_RptRefNb)

		stopreportflow $i_reportflowID
		
ENDROUTINE

*****************************************
**ROUTINE HIS_STBY2NORMAL
**Routine to switch HIS mode the Normal (generate science data)
*****************************************
ROUTINE HIS_NORMAL2STBY
	
	--Define constant
	CONST
	string $s_Trace := "TRACE"
	
	-- Define variables	
	VAR
	date $dCurDate
	int $i_reportFlowID
	int $i_RptRefNb	
	
	MAIN
		
		TA_PRINT "Put HIS into standby mode"
		
		$i_reportflowID := startreportflow("AB.TM.YIA58602")
		
		--; Put HIS into standby mode 
		--TC, ZIA58917, PIA59011, EQUAL, HVSTDBY
		@su_send({ AB.TC.ZIA58917 , \
		SHF:OBV := 0 , \
		SID:OBV := 120 , \
		PIA59011_ := "HVSTDBY"}, $s_Trace)
		
		--; Reception of:
		--TM,YIA58602 ; (5,1) SID=43802 SWA_E_HIS_MODE_CHANGE 
		@RPZA_CATCHTMPCKT($i_reportFlowID, "AB.TM.YIA58602", *$i_RptRefNb)
		stopreportflow $i_reportflowID
		
ENDROUTINE