****************************************************************************************************
** LNG product:		ELISA source
****************************************************************************************************
** Type:               			Sequence 
**  
** FOP Name & Version: 			None 
**
** Description:                    	The following sequence performs the following steps :-
**								- Switch off SWA HIS
**					
**
** Input Arguments:				None
**								
**
** Output Values:					None
**
** CSW Version:					V2.1.3 or higher
** 
** FOPs used:						None 
**
** HK TM packets used:				
**
** Test Procedure & Reference:		SO-SWA-MSSL-TOP-059 Issue 4
**
** Restrictions and Limitations: 	SSMM hardware required to be on before switch ON.
**								SWA HIS ON
**								SWA DPU to be On in OPS mode.     
**
****************************************************************************************************
**	History
**--------------------------------------------------------------------------------------------------
**	Version	Date			Author			Comment
**--------------------------------------------------------------------------------------------------
**	1.1		28/04/2018	J Silverthorn		Initial version
**	1.4		30/05/2018	E Boulet			Update sequence according to new input from SO-SWA-MSSL-TP-059 issue 4
**	1.5		05/06/2018	E Boulet			Change pass criteria for IF (sign were inverted)
**	1.6		08/06/2018	J Silverthorn		Removed capture of YIU58602 at start after mode change command
**	1.7		02/08/2018					Timeouts changed globaly to 150 seconds and in specific cases as noted in script
**	1.8		04/08/2018					Timeouts changed for ramp down delays
***************************************************************************************************

** SEQUENCE TISS_HIS_OFF

SEQUENCE TISS_HIS_OFF
	** Definition of Input parameters
	
	** Definition of Constants
	const
	string   		$sTitle  		:= "TITLE"  
	string		$sTrace 		:= "TRACE"
	
	** Definition of Variables
	var
	string		$sBufArg := ""
	string		$sNumPha
	string		$sPlatform	
	date			$dCurDate
	
	int 			$Count
	
	string 		$s_lcl_a_cur := "AB.TM.NPWD3267"											--IFA_LCL4_LCL16 SWA-A_LCL TM
	string		$s_lcl_b_cur := "AB.TM.NPWD2768"											--IFA_LCL2_LCL17 SWA-B PWR_LCL TM
	string 		$s_lcl_a_sts := "AB.TM.NPWD0077"											--IFA_LCL4_LCL16 SWA-A_LCL ST
	string		$s_lcl_b_sts := "AB.TM.NPWD0038"											--IFA_LCL2_LCL17 SWA-B PWR_LCL ST
	string 		$s_rsa_a_sts := "AB.TM.NRUD2007"											--Acq. RSA_1_1_9 SWA A
	string		$s_rsa_b_sts := "AB.TM.NRUD2067"											--Acq. RSA_2_1_9 SWA B
	
	string 		$sTTRM
	string 		$sPM
	string 		$sRIU
	string		$sPCDU
	string		$sMilBus	
	
	string		$sRSA_A
	string		$sRSA_B
	
	int $i_RptRefNb(2)
	int 			$i_reportflowID(2)
	real $rNIA01371
	real $rNIA01342
	real $rNIA04633
	real $rNIA04631
	real $rNIA04632
	real $rNIA04634
	real $rNIA01351	
	
	main
		window
		
		@SU_SEQSTART("Switching SWA HIS OFF", *$dCurDate, $sTrace, "")
		$sPlatform := AB.USR.PLATFORM
		
		@TPZC_PSFT_CONFIG(*$sTTRM,*$sPM,*$sRIU,*$sPCDU,*$sMilBus)
		
		if ($sPCDU = "B")
			$s_lcl_a_cur := "AB.TM.NPWT3267"
			$s_lcl_b_cur := "AB.TM.NPWT2768"
			$s_lcl_a_sts := "AB.TM.NPWT0077"
			$s_lcl_b_sts := "AB.TM.NPWT0038"
		endif
		if ($sRIU = "B")
			$s_rsa_a_sts := "AB.TM.NRUT2007"
			$s_rsa_b_sts := "AB.TM.NRUT2067"
		endif
		
		********************************************************************
		@SU_SEQPHASE2(1, "Initial checks", *$sNumPha, "",  $sTitle)
		********************************************************************
		
		@su_digacs($s_lcl_a_sts,"NO","NO", $sTrace, 5) 
		@su_digacs($s_lcl_b_sts,"NO","NO", $sTrace, 5) 
		@su_digacrs($s_rsa_a_sts,"NO","NO", *$sRSA_A, $sTrace, 5) 
		@su_digacrs($s_rsa_b_sts,"NO","NO", *$sRSA_B, $sTrace, 5) 
		@su_anaacs($s_lcl_a_cur,"NO","NO",$sTrace, 150) 
		@su_anaacs($s_lcl_b_cur,"NO","NO",$sTrace, 150) 
		
		if (($sRSA_A = "Off") and ($sRSA_B = "Off"))
			ta_print "Error SWA DPU is OFF - please check"
			Return "INIT_NOK"
		end if
		
		-- checks required here for High Voltage OFF
		
		@SU_SEQPHASE2(1, "Switch HIS Off", *$sNumPha, "",  $sTitle)	
		--Step 6.1.1 of SO-SWA-MSSL-TP-059 issue 4
		@SU_SEQPHASE2(2, "Put HIS into standby mode   ", *$sNumPha, "",  $sTitle)	

		@SU_SEND({ AB.TC.ZIA58917 , \
		SHF:OBV := 0 , \
		SID:OBV := 120 , \
		PIA59011_ := "HVSTDBY"}, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)

		--Step 6.1.2 of SO-SWA-MSSL-TP-059 issue 4		
		@su_wait(2)
		@RPZA_HKTM_CATCH("AB.TM.YIA58212", "WAIT" , *$Count , 120)
		
		--Step 6.1.3 of SO-SWA-MSSL-TP-059 issue 4
		@SU_ANAACRS(SNAME := "AB.TM.NIA01371", "NO", "NO", *$rNIA01371, CONF := $sTrace, TIMEOUT := 150)
		@SU_ANAACRS(SNAME := "AB.TM.NIA01342", "NO", "NO", *$rNIA01342, CONF := $sTrace, TIMEOUT := 150)
		IF(($rNIA01371 <= -0.05) OR ($rNIA01342 >= 0.05 ))		
			
			--Step 6.1.4 of SO-SWA-MSSL-TP-059 issue 4
			
			-- Ramp down Top Plate
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "TOP_PLATE", \
			PIA60354_ := 0 , \
			PIA60353_ := 0 , \
			PIA60345_ := 3 , \
			PIA59054_ := "HIGH" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			-- Ramp down Bottom Deflector
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "BOT_DFL", \
			PIA60354_ := 0 , \
			PIA60353_ := 0 , \
			PIA60345_ := 3 , \
			PIA59054_ := "HIGH" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			-- Ramp down top Deflector
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "TOP_DFL", \
			PIA60354_ := 0 , \
			PIA60353_ := 0 , \
			PIA60345_ := 3 , \
			PIA59054_ := "HIGH" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			-- Ramp down Analyzer
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "ANALYZER", \
			PIA60354_ := 0 , \
			PIA60353_ := 0 , \
			PIA60345_ := 3 , \
			PIA59054_ := "HIGH" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			--Step 6.1.5 of SO-SWA-MSSL-TP-059 issue 4 
			@su_wait(6)
			
			--Step 6.1.6 of SO-SWA-MSSL-TP-059 issue 4 
			-- Ramp down Main
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "MAIN", \
			PIA60354_ := 0 , \
			PIA60353_ := 65 , \
			PIA60345_ := 3 , \
			PIA59054_ := "NONE" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			--Step 6.1.7 of SO-SWA-MSSL-TP-059 issue 4
			@su_wait(3)
			
			--Step 6.1.8 of SO-SWA-MSSL-TP-059 issue 4
			@SU_ANAACS(SNAME := "AB.TM.NIA01371", "NO", "<=-0.05", CONF := $sTrace, TIMEOUT := 290) -- v1.8
			@SU_ANAACS(SNAME := "AB.TM.NIA01342", ">=0.05", "NO", CONF := $sTrace, TIMEOUT := 10) -- v1.7
		endif
		
		--Step 6.1.9 of SO-SWA-MSSL-TP-059 issue 4
		-- disable EAIS
		@SU_SEND({ AB.TC.ZIA58907 , \
		PIA59000_ := "DISABLE", \
		PIA59006_ := "IRAP" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
		
		--Step 6.1.10 of SO-SWA-MSSL-TP-059 issue 4		
		@SU_ANAACRS(SNAME := "AB.TM.NIA04633", "NO", "NO", *$rNIA04633, CONF := $sTrace, TIMEOUT := 150)
		IF($rNIA04633 >= 2.0)	
			
			--Step 6.1.11 of SO-SWA-MSSL-TP-059 issue 4
			-- Ramp down SSD
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "SSD", \
			PIA60354_ := 0 , \
			PIA60353_ := 164 , \
			PIA60345_ := 1 , \
			PIA59054_ := "NONE" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			--Step 6.1.12 of SO-SWA-MSSL-TP-059 issue 4
			@su_wait(1)
			
			--Step 6.1.13 of SO-SWA-MSSL-TP-059 issue 4
			@SU_ANAACS(SNAME := "AB.TM.NIA04633", ">=2", "NO", CONF := $sTrace, TIMEOUT := 150)
			
		endif
		
		--Step 6.1.14 of SO-SWA-MSSL-TP-059 issue 4
		-- disable SSD
		@SU_SEND({ AB.TC.ZIA58907 , \
		PIA59000_ := "DISABLE", \
		PIA59006_ := "SSD" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
		
		--Step 6.1.15 of SO-SWA-MSSL-TP-059 issue 4
		@SU_ANAACRS(SNAME := "AB.TM.NIA04631", "NO", "NO", *$rNIA04631, CONF := $sTrace, TIMEOUT := 150)
		@SU_ANAACRS(SNAME := "AB.TM.NIA04632", "NO", "NO", *$rNIA04632, CONF := $sTrace, TIMEOUT := 150)
		IF(($rNIA04631 >= 0.03) OR ($rNIA04632 >= 0.03 ))	
			
			--Step 6.1.16 of SO-SWA-MSSL-TP-059 issue 4
			-- Ramp down MCP
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "START_MCP", \
			PIA60354_ := 0 , \
			PIA60353_ := 12 , \
			PIA60345_ := 5 , \
			PIA59054_ := "NONE" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "STOP_MCP", \
			PIA60354_ := 0 , \
			PIA60353_ := 12 , \
			PIA60345_ := 5 , \
			PIA59054_ := "NONE" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			--Step 6.1.17 of SO-SWA-MSSL-TP-059 issue 4
			@su_wait(5)
			
			--Step 6.1.18 of SO-SWA-MSSL-TP-059 issue 4
			@SU_ANAACS(SNAME := "AB.TM.NIA04631", ">=0.03", "NO", CONF := $sTrace, TIMEOUT := 890) -- v1.8
			@SU_ANAACS(SNAME := "AB.TM.NIA04632", ">=0.03", "NO", CONF := $sTrace, TIMEOUT := 890) -- v1.8
			
		endif
		
		--Step 6.1.19 of SO-SWA-MSSL-TP-059 issue 4
		-- disable MCP
		@SU_SEND({ AB.TC.ZIA58907 , \
		PIA59000_ := "DISABLE", \
		PIA59006_ := "START_MCP" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
		
		@SU_SEND({ AB.TC.ZIA58907 , \
		PIA59000_ := "DISABLE", \
		PIA59006_ := "STOP_MCP" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
		
		--Step 6.1.20 of SO-SWA-MSSL-TP-059 issue 4		
		@SU_ANAACRS(SNAME := "AB.TM.NIA04634", "NO", "NO", *$rNIA04634, CONF := $sTrace, TIMEOUT := 150)
		IF($rNIA04634 >= 0.02)	
			
			--Step 6.1.21 of SO-SWA-MSSL-TP-059 issue 4	
			--ramp down offset	
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "OFFSET", \
			PIA60354_ := 0 , \
			PIA60353_ := 102 , \
			PIA60345_ := 5 , \
			PIA59054_ := "NONE" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			--Step 6.1.22 of SO-SWA-MSSL-TP-059 issue 4		
			@su_wait(5)
			
			--Step 6.1.23 of SO-SWA-MSSL-TP-059 issue 4		
			@SU_ANAACS(SNAME := "AB.TM.NIA04634", ">=0.02", "NO", CONF := $sTrace, TIMEOUT := 210) -- v1.8
		ENDIF
		
		--Step 6.1.24 of SO-SWA-MSSL-TP-059 issue 4	
		-- disable Offset
		@SU_SEND({ AB.TC.ZIA58907 , \
		PIA59000_ := "DISABLE", \
		PIA59006_ := "OFFSET" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
		
		--Step 6.1.25 of SO-SWA-MSSL-TP-059 issue 4		
		@SU_ANAACRS(SNAME := "AB.TM.NIA01351", "NO", "NO", *$rNIA01351, CONF := $sTrace, TIMEOUT := 150)
		IF($rNIA01351 <= -2.3)
			
			--Step 6.1.26 of SO-SWA-MSSL-TP-059 issue 4	
			--ramp down PA
			@SU_SEND({ AB.TC.ZIA58908 , \
			PIA59050_ := "PA", \
			PIA60354_ := 0 , \
			PIA60353_ := 12 , \
			PIA60345_ := 10 , \
			PIA59054_ := "NONE" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
			
			--Step 6.1.27 of SO-SWA-MSSL-TP-059 issue 4		
			@su_wait(10)
			
			--Step 6.1.28 of SO-SWA-MSSL-TP-059 issue 4		
			@SU_ANAACS(SNAME := "AB.TM.NIA01351", "NO", "<=-2.3", CONF := $sTrace, TIMEOUT := 2800)  --wait 45 min
		ENDIF	
		
		--Step 6.1.29 of SO-SWA-MSSL-TP-059 issue 4	
		-- disable PA
		@SU_SEND({ AB.TC.ZIA58907 , \
		PIA59000_ := "DISABLE", \
		PIA59006_ := "PA" }, $sTrace, VER := "AUTO", TIMEOUT_VER := 150)
		
		
		@SU_SEQPHASE2(2, "Disable DPU HIS HB monitor TC", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZIA58064 , \
		PIA60452_ := 1 , \
		PIA60449_1 := "HISHEARTB_MI" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		
		@SU_SEQPHASE2(2, "Power Down HIS for DPU disable HIS SpW", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZIA58730 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		
		@su_anaacs("AB.TM.NIA00834",">=0","<=10", $sTrace, 10)
		
		@SU_SEQPHASE2(2, "Powering off LCL HTR1", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZCSD7001 , \
		PCSB001A_ := 2 , \
		PCSB0018_1 := "DECON_HTR1_LCL" , \
		PCSB0019_1 := "PCDU_SWTCH_OFF" , \
		PCSB0018_2 := "DECON_HTR1_SSS" , \
		PCSB0019_2 := "PCDU_SWTCH_OFF" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		
		@SU_SEQPHASE2(2, "Powering off LCL HTR2", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZCSD7001 , \
		PCSB001A_ := 2 , \
		PCSB0018_1 := "DECON_HTR2_LCL" , \
		PCSB0019_1 := "PCDU_SWTCH_OFF" , \
		PCSB0018_2 := "DECON_HTR2_SSS" , \
		PCSB0019_2 := "PCDU_SWTCH_OFF" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		
		@SU_SEQPHASE2(2, "Checking LCL HTR1 is OFF", *$sNumPha, "",  $sTitle)	
		@su_digacs("AB.TM.NPWD0050","=","OFF", $sTrace, 5)
		@su_anaacs("AB.TM.NPWD3010",">=-0.1","<=0.1", $sTrace, 5)  -- Need to establish expected limits
		
		@SU_SEQPHASE2(2, "Checking LCL HTR2 is OFF", *$sNumPha, "",  $sTitle)	
		@su_digacs("AB.TM.NPWD0010","=","OFF", $sTrace, 5)
		@su_anaacs("AB.TM.NPWD2510",">=-0.1","<=0.1", $sTrace, 5)  -- Need to establish expected limits
		
		@su_SEQPHASE2(2, "Switching Relay box 1 output to OFF", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZCSD3008 , \
		PCSB0020_ := "RB1_HIS_Nom_OFF" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		@su_digacs("AB.TM.NBCD0034","NO","Off", $sTrace, 5)  -- Note NCR on TM inversion
		
		@su_SEQPHASE2(2, "Switching Relay box 2 output to OFF", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZCSD3008 , \
		PCSB0020_ := "RB2_HIS_Red_OFF" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		@su_digacs("AB.TM.NBCD0046","NO","Off", $sTrace, 5)  -- Note NCR on TM inversion
		
		@su_SEQPHASE2(2, "Resetting Relay box return relay 1 to Pos 1", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZCSD3008 , \
		PCSB0020_ := "RB2_HIS_Rt2_P1" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		@su_digacs("AB.TM.NBCD0043","NO","Pos 1", $sTrace, 5)  -- Note NCR on TM inversion
		
		@su_SEQPHASE2(2, "Resetting Relay box 1 return relay to Pos 2", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZCSD3008 , \
		PCSB0020_ := "RB1_HIS_Rt1_P2" }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 150)
		@su_digacs("AB.TM.NBCD0033","NO","Pos 2", $sTrace, 5) -- Note NCR on TM inversion
		
		
end sequence