****************************************************************************************************
** LNG product:		ELISA source
****************************************************************************************************
** Type:               			Sequence 
**  
** FOP Name & Version: 			None 
**
** Description:                    	The following sequence performs the following steps :-
**								- Switch on SWA PAS
**					
**
** Input Arguments:				None
**								
**
** Output Values:					None
**
** CSW Version:					V2.1.3 or higher
** 
** FOPs used:						None 
**
** HK TM packets used:				
**
** Test Procedure & Reference:		SO-SWA-MSSL-TOP-059 Issue 1 Section 5.3
**
** Restrictions and Limitations: 	SSMM hardware required to be on before switch ON.
**								SWA DPU to be On in OPS mode.     
**
****************************************************************************************************
**	History
**--------------------------------------------------------------------------------------------------
**	Version	Date			Author			Comment
**--------------------------------------------------------------------------------------------------
**	1.1-4	26/04/2018	J Silverthorn		Initial version
**	1.5		01/05/2018	E Boulet			Update proto to include HV safety and forbid switch on if flight conf is chosen
**	1.6		01/05/2018	E Boulet			Update capture of packet for macro
**	1.7		01/08/2018	J Silverthorn		Introduced check on parameter NIA00532 to verify correct HV disable / airsafe plug is fitted
**	1.8		02/08/2018					Introduced check on parameter NIA00524 to verify correct HV disable / airsafe plug is fitted
**										Removed check on parameter NIA00532 to verify correct HV disable / airsafe plug is fitted
**	1.9									Limits changed for acquisition of HV parameter NIA00524
**	1.10									Limits changed for acquisition of HV parameter NIA00526, removal of NIA00524
**	1.11		15/11/2018					Changes requested as prt of review prior to first formal run
**	1.12		08/12/2018					ACS-SVT-140 Obs#34 - Changes to expected temperature ranges 
**	1.13		14/02/2019	D Cowan			Added the option to not check TM (for MIST)
**	1.14									Added some TM checks back in with the TM request command
**	1.15		06/03/2019					Temperature TM limits changed
**	1.16		13/03/2019	D Cowan			Removed HV checks when TM is not enabled, as the packet cannot be forwarded to ground
**	1.17		30/08/2019	J Silervthorn		Brought in line with switch on procedure SO-SWA-MSSL-TP-059 Issue 5B
**	1.18		11/09/2019					ACS-SOL-EVT-0498 OBS #12 additional command ZIA58862
***************************************************************************************************

** SEQUENCE TISS_PAS_ON

SEQUENCE TISS_PAS_ON
	** Definition of Input parameters
	proto
		string			$sPAS_HVSafety	["AIRSAFE","DISABLED","FLIGHT"] 
		string			$TM				:= "YES"				upper ["YES","NO"]
	end proto
	
	** Definition of Constants
	const
	string   		$sTitle  		:= "TITLE"  
	string		$sTrace 		:= "TRACE"
	
	** Definition of Variables
	var
	string		$sBufArg := ""
	string		$sNumPha
	string		$sPlatform	
	date			$dCurDate
	
	int 			$Count
	int			$i_reportflowID
	int			$i_reportflowID_1
	int			$i_reportflowID_2
	int			$i_reportflowID_3
	int      		$i_RptRefNb
	int      		$i_RptRefNb_1
	int      		$i_RptRefNb_2
	int      		$i_RptRefNb_3
	
	string 		$s_lcl_a_cur := "AB.TM.NPWD3267"											--IFA_LCL4_LCL16 SWA-A_LCL TM
	string		$s_lcl_b_cur := "AB.TM.NPWD2768"											--IFA_LCL2_LCL17 SWA-B PWR_LCL TM
	string 		$s_lcl_a_sts := "AB.TM.NPWD0077"											--IFA_LCL4_LCL16 SWA-A_LCL ST
	string		$s_lcl_b_sts := "AB.TM.NPWD0038"											--IFA_LCL2_LCL17 SWA-B PWR_LCL ST
	string 		$s_rsa_a_sts := "AB.TM.NRUD2007"											--Acq. RSA_1_1_9 SWA A
	string		$s_rsa_b_sts := "AB.TM.NRUD2067"											--Acq. RSA_2_1_9 SWA B
	
	string 		$sTTRM
	string 		$sPM
	string 		$sRIU
	string		$sPCDU
	string		$sMilBus	
	
	string		$sRSA_A
	string		$sRSA_B
	
	
	main
		window
		
		@SU_SEQSTART("Switching ON SWA PAS", *$dCurDate, $sTrace, "")
		$sPlatform := AB.USR.PLATFORM
		
		IF ($sPAS_HVSafety = "FLIGHT")
			raise NOK, "There is no HV safety plug connected to PAS - switch on not allowed"
			abort
		ENDIF
		
		if ($TM = "YES")
			@TPZC_PSFT_CONFIG(*$sTTRM,*$sPM,*$sRIU,*$sPCDU,*$sMilBus)
			
			if ($sPCDU = "B")
				$s_lcl_a_cur := "AB.TM.NPWT3267"
				$s_lcl_b_cur := "AB.TM.NPWT2768"
				$s_lcl_a_sts := "AB.TM.NPWT0077"
				$s_lcl_b_sts := "AB.TM.NPWT0038"
			endif
			if ($sRIU = "B")
				$s_rsa_a_sts := "AB.TM.NRUT2007"
				$s_rsa_b_sts := "AB.TM.NRUT2067"
			endif
			
			********************************************************************
			@SU_SEQPHASE2(1, "Initial checks", *$sNumPha, "",  $sTitle)
			********************************************************************
			
			@su_digacs($s_lcl_a_sts,"NO","NO", $sTrace, 5) 
			@su_digacs($s_lcl_b_sts,"NO","NO", $sTrace, 5) 
			@su_digacrs($s_rsa_a_sts,"NO","NO", *$sRSA_A, $sTrace, 5) 
			@su_digacrs($s_rsa_b_sts,"NO","NO", *$sRSA_B, $sTrace, 5) 
			@su_anaacs($s_lcl_a_cur,"NO","NO",$sTrace, 60) 
			@su_anaacs($s_lcl_b_cur,"NO","NO",$sTrace, 60) 
			
			if (($sRSA_A = "Off") and ($sRSA_B = "Off"))
				ta_print "Error SWA DPU is OFF - please check"
				Return "INIT_NOK"
			end if
			
			@su_digacs("AB.TM.NIAD0703","=","OPS", $sTrace, 5)
			
		end if 
		
		@SU_SEQPHASE2(1, "Switch PAS ON", *$sNumPha, "",  $sTitle)	
		
		@SU_SEQPHASE2(2, "Enable PAS HK", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZIA58050 , \
		PIA58050_ := "PAS_SENS_HK"}, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)
		@su_wait(2)
			
		@SU_SEQPHASE2(2, "Run PAS Power ON", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZIA58858 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)
		@su_wait(60)

		@su_anaacs("AB.TM.NIA00535",">=56","<=120", $sTrace)
		
		@SU_SEQPHASE2(2, "Use PAS master control register to enable Main HV", *$sNumPha, "",  $sTitle)	
		@SU_SEND({ AB.TC.ZIA58863 , \
		PIA60343_ := 0x1C }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)
		@su_wait(2)
		
		if ($TM = "YES")
			
			@SU_SEQPHASE2(2, "Request a PAS HK packet", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58866 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)
			@su_wait(2)
			
			@su_anaacs("AB.TM.NIA00500",">=0","<=10", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00501",">=0","<=10", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00509",">=0","<=10", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00510",">=0","<=15", $sTrace, 10)	

			@su_anaacs("AB.TM.NIA00511",">=0","<=15", $sTrace, 10)	-- v1.18

			@su_anaacs("AB.TM.NIA00504",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00505",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00506",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00507",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00523",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00514",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00530",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00515",">=-30","<=45", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00531",">=-30","<=80", $sTrace, 10)
			@su_anaacs("AB.TM.NIA00516",">=0","<=100", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00517",">=0","<=100", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00518",">=0","<=100", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00519",">=0","<=100", $sTrace, 10)	
			@su_anaacs("AB.TM.NIA00522",">=0","<=200", $sTrace, 10)		
			
		end if
		
		if ($sPAS_HVSafety = "AIRSAFE")
			
			$i_reportflowID := startreportflow("AB.TM.YIA58012")
			
			@SU_SEQPHASE2(2, "Run PAS Config Macro", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58853 }, $sTrace, VER := "ACK", TIMEOUT_VER := 60)
			
			@SU_SEQPHASE2(2, "Wait 10 minutes", *$sNumPha, "",  $sTitle)	
			@su_wait(600)
			
			@RPZA_CATCHTMPCKT($i_reportFlowID, "AB.TM.YIA58012", *$i_RptRefNb) -- v1.11
			stopreportflow $i_reportflowID
			
			if ($TM = "YES")
				
				@SU_SEQPHASE2(2, "Checking AIRSAFE plug is fitted", *$sNumPha, "",  $sTitle)	
				@su_anaacs("AB.TM.NIA00525",">=348.0","<=695.0", $sTrace, 10)	-- v1.18 OBS #5
				
				@SU_SEQPHASE2(2, "Checking other HK", *$sNumPha, "",  $sTitle)	
				@su_anaacs("AB.TM.NIA00524",">=348.0","<=695.0", $sTrace, 10)	-- v1.18 OBS #5
				
			end if
			
			@SU_SEQPHASE2(2, "Use PAS master control register to set CEM general switch ON", *$sNumPha, "",  $sTitle)	 -- v1.11
			@SU_SEND({ AB.TC.ZIA58863 , \
			PIA60343_ := 0x1D }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60) -- v1.11
			@su_wait(2)
			
			@SU_SEQPHASE2(2, "Use PAS master control register to set CEM centr' and CEM periph' ON", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58863 , \
			PIA60343_ := 0x5 }, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60)
			@su_wait(2)
			
			@SU_SEQPHASE2(2, "Run the HV Ramp Macro", *$sNumPha, "",  $sTitle)	
			@SU_SEND({ AB.TC.ZIA58856 , \
			PIA60791_ := 0 , \
			PIA60790_ := 0xCCC , \
			PIA60792_ := 0x1FD , \
			PIA60793_ := 0x1E }, $sTrace, VER := "ACK", TIMEOUT_VER := 60)
			
			@su_wait(300)

			@SU_SEQPHASE2(2, "Command PAS pre-amp on", *$sNumPha, "",  $sTitle)	 -- v1.11
			@SU_SEND({ AB.TC.ZIA58862 , \
			SHF:OBV := 0 , \
			SID:OBV := 120 , \
			PIA58062_ := "ON" , \
			PIA58063_ := "ON"}, $sTrace, VER := "ACK_EXEC", TIMEOUT_VER := 60) -- v1.18 OBS #12
			
		endif
		
end sequence